STKBeeThree

STKBeeThree — Instrument STK de synthèse MF ressemblant à un orgue type Hammond.

Description

Instrument STK de synthèse MF ressemblant à un orgue type Hammond.

Cet opcode a une simple topologie à 4 opérateurs, aussi référencée comme l'algorithme 8 du TX81Z. Il simule le son d'un orgue type Hammond, et d'autre sons en relation.

Syntaxe

asignal STKBeeThree ifrequency, iamplitude, [kop4, kv1[, kop3, kv2[, klfo, kv3[, klfodepth, kv4[, kadsr, kv5]]]]]

Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

Exécution

kop4 -- contrôleur 2, gain et feedback de l'opérateur 4. kv1 compris entre 0 et 127.

kop3 -- contrôleur 4, gain de l'opérateur 3. kv2 compris entre 0 et 127.

klfo -- contrôleur 11, vitesse de l'oscillateur basse-fréquence. kv3 compris entre 0 et 127.

klfodepth -- contrôleur 1, intensité de l'oscillateur basse-fréquence. kv4 compris entre 0 et 127.

kadsr -- contrôleur 128, cible de l'ADSR 2 et 4. kv5 compris entre 0 et 127.

[Note] Notes

Le code pour cet opcode vient directement de la classe BeeThree du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôle facultatives au taux-k pour les opcodes STK. Chaque paire de contrôle est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Le numéro de contrôleur ainsi que la valeur associée sont des variables de taux-k. Cependant, durant l'exécution, les numéros de contrôleur sont habituellement constants tandis que les valeurs correspondantes peuvent changer à tout moment. L'ordre des paires de contrôle est arbitraire mais elles doivent apparaître après iamplitude. Il n'est pas non plus nécessaire d'utiliser toutes les paires.

Exemples

Voici un exemple de l'opcode STKBeeThree. Il utilise le fichier STKBeeThree.csd.

Exemple 920. Exemple de l'opcode STKBeeThree.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o STKBeeThree.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kv1	=	p6					;feedback of operator 4
kv2	line	p4, p3, p5				;gain of operator 3
kv5	line	0, p3, 100
ipch	=	p7

asig	STKBeeThree	cpspch(ipch), 1, 2, kv1, 4, kv2, 11, 50, 1, 0, 128, kv5
	outs	asig, asig
endin

</CsInstruments>
<CsScore>

i 1 0 2 20 100 127 8.00
i 1 + 8 120 0 0 6.09
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.