STKMandolin

STKMandolin — STKMandolin produit des sons de type mandoline.

Description

STKMandolin produit des sons de type mandoline, en utilisant des techniques de "synthèse commutée" pour modéliser une mandoline.

Syntaxe

asignal STKMandolin ifrequency, iamplitude, [kbody, kv1[, kpos, kv2[, ksus, kv3[, kdetune, kv4[, kmic, kv5]]]]]

Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

Exécution

kbody -- contrôleur 2, taille du corps. kv1 compris entre 0 et 127.

kpos -- contrôleur 4, position de pincement. kv2 compris entre 0 et 127.

ksus -- contrôleur 11, entretien de la corde. kv3 compris entre 0 et 127.

kdetune -- contrôleur 1, désaccordage de la corde. kv4 compris entre 0 et 127.

kmic -- contrôleur 128, position du microphone. kv5 compris entre 0 et 127.

[Note] Notes

Le code pour cet opcode vient directement de la classe Mandolin du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôle facultatives au taux-k pour les opcodes STK. Chaque paire de contrôle est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Le numéro de contrôleur ainsi que la valeur associée sont des variables de taux-k. Cependant, durant l'exécution, les numéros de contrôleur sont habituellement constants tandis que les valeurs correspondantes peuvent changer à tout moment. L'ordre des paires de contrôle est arbitraire mais elles doivent apparaître après iamplitude. Il n'est pas non plus nécessaire d'utiliser toutes les paires.

Exemples

Voici un exemple de l'opcode STKMandolin. Il utilise le fichier STKMandolin.csd.

Exemple 930. Exemple de l'opcode STKMandolin.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o STKMandolin.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

ifrq	=	p4
kv1	line	p5, p3, p6			;body size
kv3	=	p7				;sustain

asig	STKMandolin cpspch(ifrq), 1, 2, kv1, 4, 10, 11, kv3, 1, 100, 128, 100
	outs asig, asig
endin

</CsInstruments>
<CsScore>

i 1 0 .3 7.00 100 0 20
i 1 + .  8.00 10 100 20
i 1 + .  8.00 100 0 120
i 1 + 4  8.00 10 10 127
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

STKPlucked.

Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.