STKSimple

STKSimple — STKSimple est un instrument à table d'onde/bruit.

Description

STKSimple est un instrument à table d'onde/bruit. Il combine une onde bouclée, une source de bruit, un filtre biquadratique à résonance, un filtre à un pôle et une enveloppe ADSR pour créer quelques sons intéressants.

Syntaxe

asignal STKSimple ifrequency, iamplitude, [kpos, kv1[, kcross, kv2[, kenv, kv3[, kgain, kv4]]]]

Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

Exécution

kpos -- contrôleur 2, position du pôle du filtre. kv1 compris entre 0 et 127.

kcross -- contrôleur 4, fondu enchaîné bruit/hauteur. kv2 compris entre 0 et 127.

kenv -- contrôleur 11, taux de l'enveloppe. kv3 compris entre 0 et 127.

kgain -- contrôleur 128, gain. kv4 compris entre 0 et 127.

[Note] Notes

Le code pour cet opcode vient directement de la classe Simple du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôle facultatives au taux-k pour les opcodes STK. Chaque paire de contrôle est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Le numéro de contrôleur ainsi que la valeur associée sont des variables de taux-k. Cependant, durant l'exécution, les numéros de contrôleur sont habituellement constants tandis que les valeurs correspondantes peuvent changer à tout moment. L'ordre des paires de contrôle est arbitraire mais elles doivent apparaître après iamplitude. Il n'est pas non plus nécessaire d'utiliser toutes les paires.

Exemples

Voici un exemple de l'opcode STKSimple. Il utilise le fichier STKSimple.csd.

Exemple 939. Exemple de l'opcode STKSimple.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o STKSimple.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

ifrq	=	p4
kv1	line	p5, p3, p6				;Filter Pole Position
kv2	line	20, p3, 90				;Noise/Pitched Cross-Fade

asig	STKSimple cpspch(p4), 1, 2, kv1, 4, kv2, 11, 10, 128, 120
	outs asig, asig
endin

</CsInstruments>
<CsScore>

i 1 0 5 7.00 100 0
i 1 + .  7.05 10 127
i 1 + .  8.03 100 0
i 1 + .  5.00 10 10
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

STKClarinet.

Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.