bqrez

bqrez — Un filtre multi-modes du second ordre.

Description

Un filtre multi-modes du second ordre.

Syntaxe

ares bqrez asig, xfco, xres [, imode] [, iskip]

Initialisation

imode (facultatif, 0 par défaut) -- Le mode du filtre. Un des choix suivants :

  • 0 = passe-bas (par défaut)

  • 1 = passe-haut

  • 2 = passe-bande

  • 3 = réjecteur de bande

  • 4 = passe-tout

iskip (facultatif, 0 par défaut) -- s'il est non nul, l'initialisation du filtre est ignorée. (Nouveau dans les versions 4.23f13 et 5.0 de Csound).

Exécution

ares -- signal audio en sortie.

asig -- signal audio n entrée.

xfco -- fréquence de coupure du filtre en Hz. Peut-être de taux-i, de taux-k ou de taux-a.

xres -- importance de la résonance. Des valeurs entre 1 et 100 sont typiques. La résonance doit être supérieure ou égale à 1. Une valeur de 100 donne un gain de 20 dB à la fréquence de coupure. Peut-être de taux-i, de taux-k ou de taux-a.

Tous les modes du filtre peuvent être modulés sur la fréquence ainsi que sur la résonance.

bqrez est un filtre passe-bas résonant créé au moyen des équations du domaine s de Laplace pour les filtres passe-bas, passe-haut et passe-bande normalisées à une fréquence. On a utilisé la transformation bilinéaire contenant une constante de transformation de fréquence du domaine s dans le domaine z pour faire concorder exactement les fréquences ensemble. De nombreuses identités trigonométriques ont été utilisées pour simplifier les calculs. Il est très stable sur tout l'intervalle de travail des fréquences jusqu'à la fréquence de Nyquist.

Exemples

Voici un exemple de l'opcode bqrez. Il utilise le fichier bqrez.csd.

Exemple 95. Exemple de l'opcode bqrez emprunté de l'opcode « rezzy » dans le manuel de Kevin Conder.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o bqrez.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1			;sawtooth waveform.

kfco  line 200, p3, 2000;filter-cutoff frequency from .2 to 5 KHz.
kres  = p4		;resonance
imode = p5		;mode
asig	vco 0.2, 220, 1
afilt	bqrez asig, kfco, kres, imode
asig	balance afilt, asig
	outs asig, asig

endin

</CsInstruments>
<CsScore>
;sine wave
f 1 0 16384 10 1

i 1 0 3 1 0		; low pass
i 1 + 3 30 0		; low pass
i 1 + 3 1 1		; high pass
i 1 + 3 30 1		; high pass

e

</CsScore>
</CsoundSynthesizer>


Voir aussi

biquad, moogvcf, rezzy

Crédits

Auteur : Matt Gerassimoff
Nouveau dans la version 4.32
Ecrit en novembre 2002.