butterbr

butterbr — Un filtre de Butterworth réjecteur de bande.

Description

Implémentation d'un filtre de Butterworth réjecteur de bande du second ordre. Cet opcode peut aussi être écrit comme butbr.

Syntaxe

ares butterbr asig, xfreq, xband [, iskip]

Initialisation

iskip (facultatif, 0 par défaut) -- L'initialisation est ignorée s'il est présent et non nul.

Exécution

Ces filtres sont des filtres RII de Butterworth du second ordre. Ils sont légèrement plus lents que les filtres originaux de Csound, mais ils offrent une bande passante presque plate et une précision et une atténuation de la bande bloquée très bonnes.

asig -- Signal d'entrée à filtrer.

xfreq -- Fréquence de coupure ou centrale pour chacun des filtres.

xband -- Largeur de la bande passante ou de la bande de réjection des filtres.

Exemples

Voici un exemple de l'opcode butterbr. Il utilise le fichier butterbr.csd.

Exemple 98. Exemple de l'opcode butterbr.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o butterbr.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1	; White noise

asig rand 0.5
     outs asig, asig

endin

instr 2	; filtered noise

asig rand 0.7
abr  butterbr asig, 3000, 2000	;center frequency = 3000, bandwidth =  +/- (2000)/2, so 2000-4000 
     outs abr, abr

endin

</CsInstruments>
<CsScore>

i 1 0 2
i 2 2.5 2

e
</CsScore>
</CsoundSynthesizer>


Voir aussi

butterbp, butterhp, butterlp

Crédits

Auteur : Paris Smaragdis
MIT, Cambridge
1995

Existait dans la version 3.30

Paramètres de taux audio introduits dans la version 6.02

Octobre 2013.