c2r

c2r — Conversion du format complexe au format réel.

Description

Convertit un tableau de valeurs complexes en un tableau de valeurs réelles, en supprimant la partie imaginaire. La taille du tableau de sortie est la moitié de celle du tableau d'entrée. C'est une opération utilitaire pour faciliter les opérations sur des valeurs complexes dont le résultat est purement réel.

Syntaxe

kout[] c2r kin[]

Exécution

kout[] -- tableau de sortie contenant les valeurs réelles. Créé s'il n'existe pas.

kin[] -- tableau d'entrée contenant les valeurs complexes à parties réelle et imaginaire.

Exemples

Voici un exemple de l'opcode c2r. Il utilise le fichier c2r.csd.

Exemple 116. Exemple de l'opcode c2r.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
-d -o dac
</CsOptions>
<CsInstruments>
ksmps = 64

instr 1
ifftsize = 1024
kcnt init 0
kIn[] init  ifftsize
kOut[] init ifftsize

a1 oscili 0dbfs/2, 440

if kcnt >= ifftsize then
 kCmplx[] r2c kIn
 kSpec[] fft kCmplx
 kCmplx fftinv kSpec
 kOut c2r kCmplx
 kcnt = 0 
endif

kIn[] shiftin a1
a2 shiftout kOut
kcnt += ksmps
   out a2
endin
</CsInstruments>
<CsScore>
i1 0 10
</CsScore>
</CsoundSynthesizer>

Voir aussi

Opcodes vectoriels, Opcodes de tableaux.

Crédits

Auteur : Victor Lazzarini
NUI Maynooth
2014

Nouveau dans la version 6.04