copyf2array

copyf2array — Copie les données d'une ftable dans un vecteur.

Description

L'opcode copyf2array prend une ftable et en copie le contenu dans une t-var.

Syntaxe

copyf2array tab, kftbl

Exécution

tab -- table pour la destination.

kftbl -- ftable pour la source.

Exemple

Voici un exemple de l'opcode copyf2array. Il utilise le fichier copyf2array.csd.

Exemple 162. Exemple de l'opcode copyf2array.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-n
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

;8 points sine wave function table
giSine  ftgen   0, 0, 8, 10, 1


  instr 1
;create array
kArr[]  init    8

;copy table values in it
        copyf2array kArr, giSine
        
;print values
kndx    =       0
  until kndx == lenarray(kArr) do
        printf  "kArr[%d] = %f\n", kndx+1, kndx, kArr[kndx]
kndx    +=      1
  od

;turn instrument off
        turnoff
  endin
  
</CsInstruments>
<CsScore>
i 1 0 0.1
</CsScore>
</CsoundSynthesizer>


Voir aussi

copya2ftab

Crédits

Auteur : John ffitch
Octobre 2011

Nouveau dans la version 5.15 de Csound.