dcblock

dcblock — Un filtre bloqueur de composante continue.

Description

Implémente le filtre bloqueur de composante continue


Y[i] = X[i] - X[i-1] + (igain * Y[i-1])

Basé sur un travail de Perry Cook.

Syntaxe

ares dcblock ain [, igain]

Initialisation

igain -- le gain du filtre qui vaut 0.99 par défaut.

Exécution

ain -- signal audio en entrée.

[Note] Note

Le nouvel opcode dcblock2 présente une méthode améliorée de suppression de la composante continue d'un signal audio.

Exemples

On peut voir le résultat dans un éditeur graphique de fichiers audio comme audacity. audacity est disponible pour Linux, Windows et Mac OS et on peut le télécharger depuis http://audacity.sourceforge.net.

Voici un exemple de l'opcoce dcblock. Il utilise les fichiers dcblock.csd et beats.wav.

Exemple 185. Exemple de l'opcoce dcblock.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
;-o dcblock.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2

instr 1	;add DC to "beats.wav"

asig soundin "beats.wav"
asig = asig+5000	;adds DC of 5000
     outs asig, asig
endin

instr 2	;dcblock audio

asig soundin "beats.wav"
asig = asig+5000	;adds DC
adc  dcblock asig	;remove DC again
     outs adc, adc

endin

</CsInstruments>
<CsScore>

i 1 0 2
i 2 2 2
e

</CsScore>
</CsoundSynthesizer>


Voir aussi

dcblock2

Crédits

Auteur : John ffitch
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 3.49 de Csound.

Février 2003 : la formule a été corrigée grâce à une note d'Anders Andersson.