/

/ — Opérateur de division.

Description

Les opérateurs arithmétiques réalisent les opérations de changement de signe (négation), de conservation de signe, le ET et le OU logiques, l'addition, la soustraction, la multiplication et la division. A noter qu'une valeur ou une expression peut se trouver entre deux de ces opérateurs, pour lesquels elle sera l'argument de gauche ou l'argument de droite comme dans

a + b * c.

Dans de tels cas trois règles s'appliquent :

1. * et / s'appliquent à leurs voisins plus fortement que + et −. Ainsi l'expression ci-dessus est interprétée comme

a + (b * c)

avec * s'appliquant à b et à c et ensuite + s'appliquant à a et à b * c.

2. + et sont prioritaires par rapport à &&, qui est lui-même prioritaire par rapport à ||:

a && b - c || d

est interprété comme

(a && (b - c)) || d

3. Lorsque deux opérateurs ont le même rang de priorité, les opérations s'enchaînent de gauche à droite :

a - b - c

est interprété comme

(a - b) - c

On peut utiliser des parenthèses comme ci-dessus pour forcer un groupement particulier.

Syntaxe

a / b  (pas de restriction de taux)

où les arguments a et b peuvent être des expressions.

Arguments

Les arguments de / peuvent être des valeurs scalaires ou des tableaux (vecteurs) unidimensionnels de taux-k, ou n'importe quelle combinaison des deux. Si l'un des arguments est un tableau, la valeur retournée le sera également.

Exemples

Voici un exemple de l'opérateur /. Il utilise le fichier divides.csd.

Exemple 30. Exemple de l'opérateur /.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o /.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

idiv  = 1/p3 * p4
ktrm  oscil 1, idiv, 1						;use oscil as an envelope
printf "retrigger rate per note duration = %f\n",1, idiv
kndx  line 5, p3, 1						;vary index of FM
asig  foscil ktrm, 200, 1, 1.4, kndx, 1
      outs asig, asig

endin
</CsInstruments>
<CsScore>
f 1  0 4096 10   1    ;sine wave

i 1 0 3	10   
i 1 4 3 15  	
i 1 8 3 2 

e
</CsScore>
</CsoundSynthesizer>


Sa sortie contiendra des lignes comme celles-ci :

retrigger rate per note duration = 3.333333
retrigger rate per note duration = 5.000000
retrigger rate per note duration = 0.666667

Voir aussi

-, +, &&, ||, *, ^, %

Crédits

L'arithmétique sur les vecteurs est nouvelle dans le version 6.00