ephasor

ephasor — Produit deux sorties : un signal de phase périodique et un signal de décroissance exponentielle périodique.

Description

Cet opcode produit deux sorties : un signal de phase périodique (comme l'opcode phasor), et un signal de décroissance exponentielle périodique. Le second est synchronisé au premier, commençant à 1 et décroissant pendant que le signal de phase croît de 0 à 1. Le taux de décroissance exponentielle peut être contrôlé par le second paramètre.

Syntaxe

aexp,aphephasor kfreq, kR

Exécution

kfreq - le taux de génération des signaux de phase et exponentiel.

kR - un paramètre contrôlant le taux de décroissance du signal exponentiel, 0 < kR < 1. Les petites valeurs produisent une décroissance plus rapide.

Exemples

Voici un exemple de l'opcoce ephasor. Il utilise le fichier ephasor.csd.

Exemple 243. Exemple de l'opcode ephasor.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
</CsOptions>
<CsInstruments>

sr=44100
ksmps=64
nchnls=2
0dbfs = 1

instr 1

iamp = p4
ifr = p5
kfr expon ifr,p3,2*ifr

kfc expon 2000,p3, 4000
kq = 10
kbw = kfc/kq
kR = 1 - $M_PI*(kbw/sr)

k1 = kfc/kfr
kn = int(k1)
k1 = k1 - kn

amod,aph ephasor kfr,kR
aosc1 table aph*kn,-1,1,0,1
aosc2 table aph*(kn+1),-1,1,0,1

asig = iamp*(aosc1*(1 - k1) + aosc2*k1)*amod
  outs asig, asig
  
endin

</CsInstruments>
<CsScore>

i1 0 10 0.5 220

e
</CsScore>
</CsoundSynthesizer>

Crédits

Auteur : Victor Lazzarini
2008

Nouveau dans la version 5.10