exprandi

exprandi — Générateur de nombres aléatoires de distribution exponentielle avec interpolation (valeurs positives seulement).

Description

Générateur de nombres aléatoires de distribution exponentielle avec interpolation contrôlée entre les valeurs (valeurs positives seulement). C'est un générateur de bruit de classe x.

Syntaxe

ares exprandi klambda, xamp, xcps
ires exprandi klambda, xamp, xcps
kres exprandi klambda, xamp, xcps

Exécution

klambda -- paramètre lambda de la distribution exponentielle.

La densité de probabilité d'une distribution exponentielle est une courbe exponentielle dont la moyenne vaut 0.69515/lambda. Pour des explications plus détaillées, voir :

  1. C. Dodge - T.A. Jerse 1985. Computer music. Schirmer books. pp.265 - 286

  2. D. Lorrain. A panoply of stochastic cannons. In C. Roads, ed. 1989. Music machine . Cambridge, Massachusetts: MIT press, pp. 351 - 379.

xamp -- intervalle de distribution des nombres aléatoires.

xcps -- fréquence à laquelle de nouveau nombres sont générés.

Exemples

Voici un exemple de l'opcode exprandi. Il utilise le fichier exprandi.csd.

Exemple 255. Exemple de l'opcode exprandi.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o exprand.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1
klambda	exprandi	20, 1, 3
	printk2 klambda		; look
aout	oscili	0.8, 440+klambda, 1	; & listen
	outs	aout, aout
endin

</CsInstruments>
<CsScore>
; sine wave
f 1 0 16384 10 1

i 1 0 4
e

</CsScore>
</CsoundSynthesizer>


Voir aussi

exprand

Crédits

Auteur : John ffitch
Bath
Mai 2011
Nouveau dans la version 5.14