filesr

filesr — Retourne le taux d'échantillonnage d'un fichier son.

Description

Retourne le taux d'échantillonnage d'un fichier son.

Syntaxe

ir filesr ifilcod [, iallowraw]

Initialisation

ifilcod -- fichier son à interroger

iallowraw -- (facultatif) permet des fichiers son bruts (vaut 1 par défaut)

Exécution

filesr retourne le taux d'échantillonnage du fichier son ifilcod. filesr peut retournet le taux d'échantillonnage des fichiers de type convolve et PVOC si le paramètre iallowraw est différent de zéro (il est non nul par défaut).

Exemples

Voici un exemple de l'opcode filesr. Il utilise les fichiers filesr.csd et beats.wav.

Exemple 272. Exemple de l'opcode filenchnls.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer> 
<CsOptions> 
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o filesr.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

;after an example from Jonathan Murphy

instr 1 
;load sound into an ftable
  Sfile	    strcpy    "beats.wav" 
  ilen	    filelen   Sfile 
  isr	    filesr    Sfile 
  isamps    =  ilen * isr 
;adjust the length of the table to be a power of two closest
;to the actual size of the sound 
  isize	    init      1 
loop: 
  isize	    =  isize * 2 
  if (isize < isamps) igoto loop 
  itab	    ftgen     0, 0, isize, 1, Sfile, 0, 0, 0 
prints  "sample rate = %f, size = %f\n", isr, isize ;prints them

endin 
</CsInstruments> 
<CsScore> 
i1 0 2
e 
</CsScore> 
</CsoundSynthesizer> 


Le fichier audio « beats.wav » a été échantillonné à 44.1 KHz. Ainsi la sortie de filesr contiendra une ligne comme :

sample rate = 44100.000000, size = 131072.000000

Voir aussi

filebit, filelen, filenchnls, filepeak

Crédits

Auteur : Matt Ingalls
Juillet 1999

Nouveau dans la version 3.57 de Csound