fiopen

fiopen — Ouvre un fichier dans un mode spécifique.

Description

On peut utiliser fiopen pour ouvrir un fichier dans un des modes spécifiés.

Syntaxe

ihandle fiopen ifilename, imode

Initialisation

ihandle -- un nombre qui spécifie ce fichier.

ifilename -- le nom du fichier concerné (entre guillemets).

imode -- choix du mode d'ouverture du fichier. imode peut prendre une des valeurs suivantes :

  • 0 - ouvre un fichier texte en écriture

  • 1 - ouvre un fichier texte en lecture

  • 2 - ouvre un binaire texte en écriture

  • 3 - ouvre un fichier binaire en lecture

Exécution

fiopen ouvre un fichier à utiliser par la famille d'opcodes fout. Il est plus sûr de l'utiliser dans la section d'en-tête, en dehors de tout instrument. Il retourne un nombre, ihandle, qui fait référence de manière univoque au fichier ouvert.

Si fiopen est appelé sur un fichier déjà ouvert, il retourne simplement le même identificateur, et ne ferme pas le fichier.

Noter que fout et foutk peuvent utiliser soit un nom de chemin de fichier, soit un identificateur numérique généré par fiopen. Alors qu'avec fouti et foutir, le fichier cible ne peut être spécifié que par un identificateur numérique.

Exemples

Voici un exemple de l'opcode fiopen. Il utilise le fichier fiopen.csd. Noter que l'exemple doit être exécuté depuis un répertoire dans lequel l'écriture est autorisée.

Exemple 275. Exemple de l'opcode fiopen.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
 
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o fiopen.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>
 

sr = 44100 
ksmps = 32 
nchnls = 2 
0dbfs  = 1 

gihand fiopen "test1.txt", 0 

instr 1

ires  random  0, 100
      fouti gihand, 0, 1, ires 
      ficlose gihand 

endin 
</CsInstruments>
<CsScore>
 

i 1 0 1 

e
</CsScore>
</CsoundSynthesizer>


Voir aussi

ficlose fout, fouti, foutir, foutk

Crédits

Auteur : Gabriel Maldonado
Italie
1999

Nouveau dans la version 3.56 de Csound