ftsave

ftsave — Sauvegarde dans un fichier un ensemble de tables préalablement allouées.

Description

Sauvegarde dans un fichier un ensemble de tables préalablement allouées.

Syntaxe

ftsave "filename", iflag, ifn1 [, ifn2] [...]

Initialisation

"filename" -- Une chaîne de caractères entre guillemets contenant le nom du fichier à sauvegarder.

iflag -- Type du fichier à sauvegarder (0 = binaire, différent de 0 = fichier texte).

ifn1, ifn2, ... -- Numéros des tables à sauvegarder.

Exécution

ftsave sauvegarde une liste de tables dans un fichier. Le format du fichier peut être binaire ou texte.

[Avertissement] Avertissement

Le format du fichier n'est pas compatible avec un fichier WAV et l'ordre des octets (endianness) n'est pas sûr.

Exemples

Voici un exemple de l'opcode ftsave. Il utilise le fichier ftsave.csd.

Exemple 366. Exemple de l'opcode ftsave.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac           -iadc    ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o ftsave.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; Initialize the global variables.
sr = 44100
kr = 4410
ksmps = 10
nchnls = 1

; Table #1, make a sine wave using the GEN10 routine.
gitmp1 ftgen 1, 0, 32768, 10, 1
; Table #2, create an empty table.
gitmp2 ftgen 2, 0, 32768, 7, 0, 32768, 0

; Instrument #1 - a basic oscillator.
instr 1
  kamp = 20000
  kcps = 440
  ; Use Table #1.
  ifn = 1

  a1 oscil kamp, kcps, ifn
  out a1
endin


; Instrument #2 - Load Table #1 into Table #2.
instr 2
  ; Save Table #1 to a file called "table1.ftsave".
  ftsave "table1.ftsave", 0, 1

  ; Load the "table1.ftsave" file into Table #2.
  ftload "table1.ftsave", 0, 2

  kamp = 20000
  kcps = 440
  ; Use Table #2, it should contain Table #1's sine wave now.
  ifn = 2

  a1 oscil kamp, kcps, ifn
  out a1
endin


</CsInstruments>
<CsScore>

; Play Instrument #1 for 1 second.
i 1 0 1
; Play Instrument #2 for 1 second.
i 2 2 1
e


</CsScore>
</CsoundSynthesizer>


Voir aussi

ftloadk, ftload, ftsavek

Crédits

Auteur : Gabriel Maldonado

Exemple écrit par Kevin Conder.

Nouveau dans la version 4.21