gaussi

gaussi — Générateur de nombres aléatoires à distribution gaussienne avec interpolation.

Description

Générateur de nombres aléatoires à distribution gaussienne avec interpolation contrôlée entre les valeurs. C'est un générateur de bruit de classe x.

Syntaxe

ares gaussi krange, xamp, xcps
ires gaussi krange, xamp, xcps
kres gaussi krange, xamp, xcps

Exécution

krange -- l'intervalle des nombres aléatoires (-krange à +krange). Produit des nombres positifs et négatifs.

gaussi retourne des nombres aléatoires suivant une distribution normale centrée sur 0 (mu = 0.0) avec une variance (sigma) de krange / 3.83. Ainsi plus de 99.99% des valeurs aléatoires générées sont comprises entre -krange et +krange. Si l'on veut une valeur moyenne différente de 0.0, il faut ajouter cette valeur moyenne à chaque nombre généré (voir l'exemple ci-dessous).

Pour des explications plus détaillées, voir :

  1. C. Dodge - T.A. Jerse 1985. Computer music. Schirmer books. pp.265 - 286

  2. D. Lorrain. A panoply of stochastic cannons. In C. Roads, ed. 1989. Music machine . Cambridge, Massachusetts: MIT press, pp. 351 - 379.

xamp -- intervalle de distribution des nombres aléatoires.

xcps -- fréquence à laquelle de nouveau nombres sont générés.

Exemples

Voici un exemple de l'opcode gaussi. Il utilise le fichier gaussi.csd.

Exemple 371. Exemple de l'opcode gaussi.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o exprand.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1
klambda	gaussi	100, 1, 3
	printk2 klambda		; look
aout	oscili	0.8, 440+klambda, 1	; & listen
	outs	aout, aout
endin

</CsInstruments>
<CsScore>
; sine wave
f 1 0 16384 10 1

i 1 0 4
e

</CsScore>
</CsoundSynthesizer>


Voir aussi

gauss

Crédits

Auteur : John ffitch
Bath
Mai 2011
Nouveau dans la version 5.14