genarray_i

genarray_i — Génère un vecteur à partir d'une suite arithmétique.

Description

Génère un vecteur (tableau unidimensionnel de taux-k) à partir d'une suite arithmétique durant l'initialisation.

Syntaxe

karray genarray_i istart, iend[, inc]

Initialisation

istart -- indice dans le tableau où placer le premier élément.

iend -- indice dans le tableau où placer le dernier élément.

inc -- incrément entre deux valeurs (1 par défaut).

Exemples

Voici un exemple de l'opcode genarray_i. Il utilise le fichier genarray_i.csd.

Exemple 376. Exemple de l'opcode genarray_i.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-n
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

;create and fill two arrays
kArr1[] genarray_i 1, 6
kArr2[] genarray_i 1, 6, 2/3

;print the content of kArr1
        printf  "%s", 1, "kArr1: start=1, end=6, step=default\n"
kndx    =       0
  until kndx == lenarray(kArr1) do
        printf  "kArr[%d] = %f\n", kndx+1, kndx, kArr1[kndx]
kndx    +=      1
  od

;print the content of kArr2
        printf  "%s", 1, "kArr2: start=1, end=6, step=2/3\n"
kndx    =       0
  until kndx == lenarray(kArr2) do
        printf  "kArr[%d] = %f\n", kndx+1, kndx, kArr2[kndx]
kndx    +=      1
  od

        turnoff
endin

</CsInstruments>
<CsScore>
i 1 0 1
</CsScore>
</CsoundSynthesizer>


Voir aussi

Opcodes vectoriels, fillarray

Crédits

Auteur : John ffitch
Codemist Ltd
2013

Nouveau dans la version 6.00