hdf5write

hdf5write — Ecrit des signaux et des tableaux dans un fichier hdf5.

Description

hdf5write writes N signals and arrays to a specified hdf5 file.

Syntaxe

hdf5write ifilename, xout1[, xout2, xout3, ..., xoutN]

Initialisation

ifilename -- le nom du fichier hdf5 ( entre guillemets). Si le fichier n'existe pas, il est créé.

Exécution

xout1, ...,xoutN -- signaux ou tableaux à écrire dans le fichier hdf5. Cet opcode accepte des signaux de taux-i, taux-k, taux-a ou des tableaux de taux-i, taux-k, taux-a, de n'importe quelle dimension. Ces signaux ou ces tableaux sont écrits dans un ensemble de données du fichier hdf5 utilisant le même nom de variable que dans Csound. Par exemple, si la variable Csound s'appelle 'ksignal', le nom de l'ensemble de données hdf5 sera 'ksignal'. N'importe quel nombre d'ensemble de données de différents types peuvent être écrits à chaque appel de cet opcode.

Exemples

Voici un exemple de l'opcode hdf5write. Il utilise le fichier hdf5write.csd.

Exemple 386. Exemple de l'opcode hdf5write.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
-odac
</CsOptions>
<CsInstruments>
nchnls = 2
0dbfs = 1
ksmps = 8
sr = 44100

instr hdf5write

    aArray[] init 2,2 ; Initialise a 2 X 2 a-rate array

    aArray[0][0] vco2 0.2, 100 ; Fill array with vco2 signals
    aArray[0][1] vco2 0.4, 200
    aArray[1][0] vco2 0.8, 300
    aArray[1][1] vco2 1, 400

    aVar vco2 0.2, 100 ; Initialise an a-rate variable with a vco2 signal

    kVar phasor 1 ; Initalise a k-rate variable with a phasor signal

    hdf5write "example.h5", aArray, aVar, kVar ; Write variables to an hdf5 file

endin

</CsInstruments>
<CsScore>

i "hdf5write" 0 1

</CsScore>
</CsoundSynthesizer>


Voir aussi

hdf5read

Crédits

Auteur : Edward Costello;
NUIM, 2014