jitter

jitter — Génère aléatoirement une suite de segments de droite.

Description

Génère aléatoirement une suite de segments de droite.

Syntaxe

kout jitter kamp, kcpsMin, kcpsMax

Exécution

kamp -- Amplitude de la déviation de jitter

kcpsMin -- Vitesse minimale des variations aléatoires de fréquence (exprimée en cps)

kcpsMax -- Vitesse maximale des variations aléatoires de fréquence (exprimée en cps)

jitter génère aléatoirement une suite de segments de droite entre -kamp et +kamp. La durée de chaque segment est une valeur aléatoire générée en fonction des valeurs kcpsmin et kcpsmax.

On peut utiliser jitter pour donner plus de naturel et une « touche analogique » à des sons statiques et monotones. Pour de meilleurs résultats il est conseillé de garder une amplitude modérée.

Exemples

Voici un exemple de l'opcode jitter. Il utilise le fichier jitter.csd.

Exemple 446. Exemple de l'opcode jitter.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o jitter.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kamp    init p4
kcpsmin init 4
kcpsmax init 8

kj2  jitter kamp, kcpsmin, kcpsmax
aout pluck 1, 200+kj2, 1000, 0, 1
aout dcblock aout	;remove DC
     outs aout, aout

endin
</CsInstruments>
<CsScore>

i 1 0 15 2	;a bit jitter
i 1 8 15 10	;some more
i 1 16 15 20	;lots more
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

jitter2, vibr, vibrato

Crédits

Auteur : Gabriel Maldonado

Nouveau dans la version 4.15