limit

limit — Fixe les limites inférieure et supérieure de la valeur à traiter.

Description

Fixe les limites inférieure et supérieure de la valeur à traiter.

Syntaxe

ares limit asig, klow, khigh
ires limit isig, ilow, ihigh
kres limit ksig, klow, khigh
ires[] limit isig[], ilow, ihigh
kres[] limit ksig[], klow, khigh

Initialisation

isig -- signal d'entrée

ilow -- limite inférieure

ihigh -- limite supérieure

Exécution

xsig -- signal d'entrée

klow -- limite inférieure

khigh -- limite supérieure

limit fixe les limites inférieure et supérieure pour la valeur du xsig qu'il traite. Sixhigh est inférieur à xlow, la sortie est la moyenne des deux - elle n'est pas affectée par xsig.

Cet opcode est utile dans plusieurs situations, telles que l'indexation de table ou pour l'écrêtage et le modelage de signaux de taux-a, de taux-i ou de taux-k.

Exemples

Voici un exemple de l'opcode limit. Il utilise le fichier limit.csd.

Exemple 454. Exemple de l'opcode limit.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o limit.wav -W  ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100 
ksmps = 32 
0dbfs  = 1 
nchnls = 2

instr    1 ; Limit / Mirror / Wrap

igain    = p4				;gain
ilevl1   = p5				; + level
ilevl2   = p6				; - level
imode    = p7				;1 = limit, 2 = mirror, 3 = wrap

ain   soundin  "fox.wav"
ain   = ain*igain

if    imode = 1 goto limit
if    imode = 2 goto mirror

asig  wrap  ain, ilevl2, ilevl1
goto  outsignal

limit:
asig  limit  ain, ilevl2, ilevl1
goto  outsignal

mirror:
asig  mirror  ain, ilevl2, ilevl1
outsignal:

outs  asig*.5, asig*.5			;mind your speakers
  
endin

</CsInstruments>
<CsScore>

;           Gain  +Levl -Levl Mode
i1  0  3    4.00  .25  -1.00   1	;limit
i1  4  3    4.00  .25  -1.00   2	;mirror
i1  8  3    4.00  .25  -1.00   3	;wrap
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

mirror, wrap

Crédits

Auteur : Robin Whittle
Australie

Nouveau dans la version 3.46 de Csound