lowres

lowres — Un autre filtre passe-bas à résonance.

Description

lowres est un filtre passe-bas à résonance.

Syntaxe

ares lowres asig, kcutoff, kresonance [, iskip]

Initialisation

iskip -- disposition initiale de la mémoire interne. Une valeur de zéro efface la mémoire ; une valeur différente de zéro permet de maintenir l'information précédente. La valeur par défaut est 0.

Exécution

asig -- signal d'entrée

kcutoff -- fréquence de coupure du filtre

kresonance -- quantité de résonance

lowres est un filtre passe-bas à résonance dérivé d'un orchestre écrit par Hans Mikelson. Cette implémentation est bien plus rapide que celle écrite dans le langage de Csound, et elle permet d'avoir un kr inférieur à sr. kcutoff n'étant pas en Hz et kresonance pas en dB, il faut expérimenter pour obtenir les meilleurs résultats.

Exemples

Voici un exemple de l'opcode lowres. Il utilise le fichier lowres.csd.

Exemple 469. Exemple de l'opcode lowres.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o lowres.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kres = p4
asig vco .2, 220, 1		;sawtooth

kcut line 1000, p3, 10		;note: kcut is not in Hz
as   lowres asig, kcut, kres	;note: kres is not in dB
aout balance as, asig		;avoid very loud sounds
     outs aout, aout

endin
</CsInstruments>
<CsScore>
; a sine
f 1 0 16384 10 1

i 1 0 4 3
i 1 + 4 30
i 1 + 4 60
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

lowresx

Crédits

Auteur : Gabriel Maldonado (adapté par John ffitch)
Italie

Nouveau dans la version 3.49 de Csound.