lowresx

lowresx — Simule des couches de filtres passe-bas à résonance connectés en série.

Description

lowresx est équivalent à plusieurs étages de lowres connectés en série, avec les mêmes arguments.

Syntaxe

ares lowresx asig, xcutoff, xresonance [, inumlayer] [, iskip]

Initialisation

inumlayer -- nombre d'éléments dans une aggrégation lowresx. La valeur par défaut est 4. Il n'y a pas de maximum.

iskip -- disposition initiale de la mémoire interne. Une valeur de zéro efface la mémoire ; une valeur différente de zéro permet de maintenir l'information précédente. La valeur par défaut est 0.

Exécution

asig -- signal d'entrée

xcutoff -- fréquence de coupure du filtre

xresonance -- quantité de résonance

lowresx est équivalent à plusieurs étages de lowres connectés en série, avec les mêmes arguments. Plus il y a de filtres dans l'aggrégation et plus la coupure est raide. C'est plus rapide que d'utiliser un plus grand nombre d'instances de lowres dans un orchestre de Csound parce que ne sont nécessaires qu'une seule initialisation et qu'un cycle k à la fois, et que la boucle audio est entièrement contenue dans la mémoire cache du processeur. Basé sur un orchestre par Hans Mikelson.

Exemples

Voici un exemple de l'opcode lowresx. Il utilise le fichier lowresx.csd.

Exemple 470. Exemple de l'opcode lowresx.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o lowresx.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kres = p4
inumlayer = 4

kenv linseg 0, p3*.1, 1, p3*.8, 1, p3*.1, 0 	;envelope
asig vco .3 * kenv, 220, 1			;sawtooth
kcut line 30, p3, 1000				;note: kcut is not in Hz
alx  lowresx asig, kcut, kres, inumlayer	;note: kres is not in dB
aout balance alx, asig				;avoid very loud sounds
     outs aout, aout

endin
</CsInstruments>
<CsScore>
;sine wave
f 1 0 16384 10 1

i 1 0 5 1
i 1 + 5 3
i 1 + 5 20
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

lowres

Crédits

Auteur : Gabriel Maldonado (adapté par John ffitch)
Italie

Nouveau dans la version 3.49 de Csound.

Paramètres de taux audio introduits dans la version 6.02

Octobre 2013.