lposcil3

lposcil3 — Lit un son échantillonné depuis une table en haute précision avec interpolation cubique.

Description

Lit un son échantillonné (mono ou stéréo) depuis une table, avec boucle et haute précision. lposcil3 utilise l'interpolation cubique.

Syntaxe

ares lposcil3 kamp, kfreqratio, kloop, kend, ifn [, iphs]

Initialisation

ifn -- numéro de la table de fonction

Exécution

kamp -- amplitude

kfreqratio -- facteur de multiplication de la fréquence de la table (par exemple : 1 = fréquence originale, 1.5 = une quinte ascendante, 0.5 = une octave descendante)

kloop -- début de la boucle (en échantillons)

kend -- fin de la boucle (en échantillons)

lposcil3 (looping precise oscillator) permet de faire varier au taux-k le début et la fin d'un son échantillonné contenu dans une table (GEN01). Peut être utile pour lire une boucle d'échantillons depuis une table d'onde, avec une vitesse de répétition variant durant l'exécution.

Exemples

Voici un exemple de l'opcode lposcil3. Il utilise le fichier lposcil3.csd.

Exemple 500. Exemple de l'opcode lposcil3.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o lposcil3.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kcps  = 1.5			; a fifth up
kloop = 0			; loop start time (in samples)
kend line 45000, p3, 10000	; vary loop end time (in samples)

asig lposcil3 1, kcps, kloop, kend, 1
     outs asig, asig

endin
</CsInstruments>
<CsScore>
; Its table size is deferred,
; and format taken from the soundfile header.
f 1 0 0 1 "beats.wav" 0 0 0

; Play Instrument #1 for 6 seconds.
; This will loop the drum pattern several times.
i 1 0 6

e
</CsScore>
</CsoundSynthesizer>


Voir aussi

lposcil

Crédits

Auteur : Gabriel Maldonado
Italie

Nouveau dans la version 3.52 de Csound