maxarray

maxarray — Retourne la valeur maximale dans un tableau.

Description

L'opcode maxarray retourne la valeur maximale dans un tableau de taux-k, et éventuellement son indice.

Syntaxe

kmax [,kindx] maxarray karray

Exécution

kmax -- variable pour le résultat.

kindx -- position (indice) du résultat dans le tableau.

karray -- tableau à lire.

Exemples

Voici un exemple de l'opcode maxarray. Il utilise le fichier maxarray.csd.

Exemple 526. Exemple de l'opcode maxarray.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-n 
</CsOptions>
<CsInstruments>
ksmps = 32
;example by joachim heintz

           seed       0

instr 1
;create an array with 10 elements
kArr[]     init       10
;fill in random numbers and print them out
kIndx      =          0
  until kIndx == 10 do
kNum       random     -100, 100
kArr[kIndx] =         kNum
           printf     "kArr[%d] = %10f\n", kIndx+1, kIndx, kNum
kIndx      +=         1
  od
;investigate maximum number and print it out
kMax, kMaxIndx maxarray kArr
           printf     "Maximum of kArr = %f at index %d\n", kIndx+1, kMax, kMaxIndx
           turnoff
endin


</CsInstruments>
<CsScore>
i1 0 0.1
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

minarray, sumarray, scalearray,

Crédits

Auteur : John ffitch
Octobre 2011

Nouveau dans la version 5.14 de Csound.

Révisé dans la version 6.00 de Csound pour fonctionner avec les tableau multidimensionnels.