midictrl

midictrl — Donne la valeur actuelle (0-127) d'un contrôleur MIDI spécifié.

Description

Donne la valeur actuelle (0-127) d'un contrôleur MIDI spécifié.

Syntaxe

ival midictrl inum [, imin] [, imax]
kval midictrl inum [, imin] [, imax]

Initialisation

inum -- numéro de contrôleur MIDI (0-127)

imin, imax -- Ajuste les limites minimale et maximales pour les valeurs obtenues.

Exécution

Donne la valeur actuelle (0-127) d'un contrôleur MIDI spécifié.

Avertissement

midictrl doit être utilisé seulement pour les notes déclenchées par MIDI, permettant la disponibilité d'un numéro de canal associé. Pour les notes activée depuis la partition, les évènements de ligne, ou l'orchestre, il faut utiliser l'opcode ctrl7 qui prend un numéro de canal explicite.

Exemples

Voici un exemple de l'opcode midictrl. Il utilise le fichier midictrl.csd

Exemple 514. Exemple de l'opcode midictrl.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac  -+rtmidi=virtual -M0   ;;;realtime audio out and realtime midi in
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o midictrl.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1
 	 
icps	cpsmidi	 	 
iamp	ampmidi	.5
ips	midictrl 9, 10, 500		;controller 9	 
 	 	 	 
kenv	madsr	0.5, 0, 1, 0.5
asig	pluck	kenv, icps, ips, 2, 1	;change tone color	 
	outs	asig, asig			
	 
endin
</CsInstruments>
<CsScore>
f 2 0 4096 10 1	;sine wave
; no score events allowed
f0 30	;runs 30 seconds
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

aftouch, ampmidi, cpsmidi, cpsmidib, notnum, octmidi, octmidib, pchbend, pchmidi, pchmidib, veloc

Crédits

Auteur : Barry L. Vercoe - Mike Berry
MIT - Mills
Mai 1997

Merci à Rasmus Ekman pour avoir indiqué le bon intervalle pour le numéro de contrôleur.