monitor

monitor — Retourne la trame audio de spout.

Description

Retourne la trame audio de spout (s'il est actif), sinon retourne zéro.

Syntaxe

aout1 [,aout2 ... aoutX] monitor
aarra monitor

Exécution

Dans sa forme tableau, il lit tous les canaux vers un tableau unidimensionnel.

Cet opcode peut être utilisé pour surveiller le signal de sortie de Csound. Il ne faut pas l'utiliser pour un traitement en aval du signal.

Voir l'article sur l'opcode fout pour un exemple de l'utilisation de monitor.

Exemples

Voici un exemple de l'opcode monitor. Il utilise le fichier monitor.csd.

Exemple 545. Exemple de l'opcode monitor.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o monitor.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

giSine ftgen 0, 0, 2^10, 10, 1

instr 1

asig poscil3 .5, 880, giSine
;write a raw file: 32 bits with header
     fout "fout_880.wav", 15, asig	
     outs asig, asig

endin

instr 2

klfo lfo 1, 2, 0
asig poscil3 .5*klfo, 220, giSine
;write an aiff file: 32 bits with header
     fout "fout_aif.aiff", 25, asig	
;        fout "fout_all3.wav", 14, asig
     outs asig, asig

endin

instr 99 ;read the stereo csound output buffer

allL, allR monitor
;write the output of csound to an audio file
;to a wav file: 16 bits with header
           fout "fout_all.wav", 14, allL, allR

endin
</CsInstruments>
<CsScore>

i 1 0 2
i 2 0 3
i 99 0 3
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

fout, les opcodes Mixer et le Système de Patch Zak.

Crédits

Istvan Varga 2006

John ffitch 2016, pour la forme tableau, nouveau dans la version 6.08