moog

moog — Emulation d'un synthétiseur mini-Moog.

Description

Emulation d'un synthétiseur mini-Moog.

Syntaxe

ares moog kamp, kfreq, kfiltq, kfiltrate, kvibf, kvamp, iafn, iwfn, ivfn

Initialisation

iafn, iwfn, ivfn -- les trois numéros des tables contenant la forme d'onde de l'attaque (non bouclée), la forme d'onde de la boucle principale, et la forme d'onde du vibrato. Les fichiers mandpluk.aiff et impuls20.aiff conviennent bien pour les deux premières et une sinusoïde fera l'affaire pour la troisième.

[Note] Note

Les fichiers « mandpluk.aiff » et « impuls20.aiff » sont aussi disponibles à ftp://ftp.cs.bath.ac.uk/pub/dream/documentation/sounds/modelling/.

Exécution

kamp -- amplitude de la note.

kfreq -- fréquence de la note.

kfiltq -- Q du filtre, compris entre 0,8 et 0,9

kfiltrate -- taux de contrôle pour le filtre, compris entre 0 et 0,0002

kvibf -- fréquence du vibrato en Hertz. L'intervalle conseillé va de 0 à 12

kvamp -- amplitude du vibrato

Exemples

Voici un exemple de l'opcode moog. Il utilise les fichiers moog.csd, mandpluk.aiff et impuls20.aiff.

Exemple 546. Exemple de l'opcode moog.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o moog.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kfreq  = cpspch(p4)
kfiltq = p5
kfiltrate = 0.0002
kvibf  = 5
kvamp  = .01
;low volume is needed
asig moog .15, kfreq, kfiltq, kfiltrate, kvibf, kvamp, 1, 2, 3
     outs asig, asig

endin
</CsInstruments>
<CsScore>

f 1 0 8192 1 "mandpluk.aiff" 0 0 0
f 2 0 256 1 "impuls20.aiff" 0 0 0
f 3 0 256 10 1	; sine

i 1 0 3 6.00 .1
i 1 + 3 6.05 .89
i 1 + 3 6.09 .50
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : John ffitch (d'après Perry Cook)
Université de Bath, Codemist Ltd.
Bath, UK

Nouveau dans la version 3.47 de Csound