moogladder

moogladder — Filtre passe-bas en échelle de Moog.

Description

moogladder est une nouvelle implémentation numérique du filtre en échelle de Moog, basée sur le travail d'Antti Huovilainen décrit dans le papier "Non-Linear Digital Implementation of the Moog Ladder Filter" (Proceedings of DaFX04, Université de Naples). Cette implémentation est probablement une représentation numérique plus précise du filtre analogique original.

Syntaxe

asig moogladder ain, kcf, kres[, istor]
asig moogladder ain, acf, kres[, istor]
asig moogladder ain, kcf, ares[, istor]
asig moogladder ain, acf, ares[, istor]

Initialisation

istor -- état initial de l'espace de données interne. Comme le filtrage comprend une boucle de rétroaction sur la sortie précédente, l'état initial de l'espace de stockage utilisé est significatif. Une valeur nulle provoquera l'effacement de cet espace ; une valeur non nulle autorisera la persistance de l'information précédente. La valeur par défaut est 0.

Exécution

asig -- signal d'entrée.

kcf/acf -- fréquence de coupure du filtre.

kres/ares -- résonance, généralement < 1, mais pas limitée à cette valeur. Les valeurs de résonance supérieures à 1 peuvent produire des bruits de repliement ; les synthétiseurs analogiques permettent généralement d'avoir des résonances supérieures à 1.

Exemples

Voici un exemple de l'opcode moogladder. Il utilise le fichier moogladder.csd.

Exemple 630. Exemple de l'opcode moogladder.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o moogladder.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kfe  expseg 500, p3*0.9, 1800, p3*0.1, 3000
asig buzz  1, 100, 20, 1
kres line .1, p3, .99	;increase resonance
afil moogladder asig, kfe, kres
     outs afil, afil

endin
</CsInstruments>
<CsScore>
f 1 0 4096 10 1

i 1 0 10
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Victor Lazzarini
Janvier 2005

Nouveau greffon dans la version 5

Janvier 2005.

Paramètres de taux audio introduits dans la version 6.02

Octobre 2013.