outkc

outkc — Envoie des messages de contrôleur MIDI au taux-k.

Description

Envoie des messages de contrôleur MIDI au taux-k.

Syntaxe

outkc kchn, knum, kvalue, kmin, kmax

Exécution

kchn -- numéro de canal MIDI (1-16)

knum -- numéro du contrôleur (0-127 par exemple 1 = Mollette de Modulation, 2 = Contrôleur de Souffle, etc.)

kvalue -- valeur en virgule flottante

kmin -- valeur minimale en virgule flottante (convertie en valeur entière MIDI 0)

kmax -- valeur maximale en virgule flottante (convertie en valeur entière MIDI 127 (7 bit))

outkc envoie au taux-k des messages de contrôleur sur le périphérique MIDI OUT. Il ne fonctionne qu'avec les instruments MIDI qui les reconnaissent. Il peut piloter une valeur différente de paramètre pour chaque note active.

Il peut échelonner un argument de taux-i en virgule flottante selon les valeurs kmin et kmax. Par exemple avec kmin = 1.0 et kmax = 2.0, lorque l'argument kvalue reçoit la valeur 2.0, l'opcode envoie la valeur 127 sur le périphérique MIDI OUT. Lorsque l'argument kvalue reçoit la valeur 1.0, il envoie la valeur 0. Les opcodes de taux-k envoient un message chaque fois que la valeur MIDI traduite de l'argument kvalue change.

Exemples

Voici un exemple de l'opcode outkc. Il utilise le fichier outkc.csd.

Exemple 609. Exemple de l'opcode outkc.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac -Q1 -M0  ;;;realtime audio out and midi in and out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o outkc.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2

instr 1

ikey notnum 
ivel  veloc

kcut linseg 100, .5, 20		;vary controller in .5 second
kbrt = int(kcut)		;whole numbers only
outkc 1, 74, kbrt, 0, 127	;controller 74 (= brightness)
midion 1, ikey, ivel		;of external synth

endin
</CsInstruments>
<CsScore>
f0 30	;runs 30 seconds

e
</CsScore>
</CsoundSynthesizer>


Voir aussi

outiat, outic14, outic, outipat, outipb, outipc, outkat, outkc14, outkpat, outkpb, outkpc

Crédits

Auteur : Gabriel Maldonado
Italie

Nouveau dans la version 3.47 de Csound.

Merci à Rasmus Ekman pour avoir indiqué les intervalles corrects pour le canal MIDI et les numéros de contrôleur.