outleta

outleta — Envoie un signal de taux-a depuis un port nommé d'un instrument.

Description

Envoie un signal de taux-a depuis un port nommé d'un instrument.

Syntaxe

outleta Sname, asignal

Initialisation

Sname -- Nom sous forme de chaîne de caractères du port sortant. Le nom du connecteur sortant est qualifié implicitement par le nom ou le numéro de l'instrument, si bien qu'il est permis d'utiliser le même nom de connecteur sortant dans plus d'un instrument (mais par contre on ne peut pas utiliser deux fois le même nom de connecteur sortant dans un instrument).

Exécution

asignal -- signal audio en sortie.

Durant l'exécution, le signal de taux-a passant par le connecteur sortant est envoyé à chaque instance d'un instrument contenant un connecteur entrant auquel ce connecteur sortant a été relié au moyen de l'opcode connect. Les signaux de tous les connecteurs sortants reliés à un connecteur entrant sont additionnés dans le connecteur entrant.

Exemples

Voici un exemple de l'opcode outleta. Il utilise le fichier outleta.csd.

Exemple 643. Exemple de l'opcode outleta.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o outleta.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1 

connect	 "1", "Outl", "reverby", "InL" 
connect	 "1", "Outr", "reverby", "InR" 

alwayson "reverby", 1

instr 1

aIn diskin2 "fox.wav", 1 
    outleta "Outl", aIn 
    outleta "Outr", aIn 

endin 

instr reverby

aInL   inleta "InL" 
aInR   inleta "InR" 

al, ar reverbsc	aInL, aInR, 0.7, 21000 
ifxlev = 0.5 
al     = (aInL*ifxlev)+(al*(1-ifxlev)) 
ar     = (aInR*ifxlev)+(ar*(1-ifxlev)) 
       outs al, ar 
                                
endin 
</CsInstruments>
<CsScore>

i 1 0 3 
e4
</CsScore>
</CsoundSynthesizer>


Voir aussi

outletk, outletkid, outletf, inleta, inletk, inletkid, inletf, connect, alwayson, ftgenonce.

Plus d'information sur cet opcode : http://www.csoundjournal.com/issue13/signalFlowGraphOpcodes.html, écrit par Michael Gogins.

Crédits

Par Michael Gogins, 2009