outletk

outletk — Envoie un signal de taux-k depuis un port nommé d'un instrument.

Description

Envoie un signal de taux-k depuis un port nommé d'un instrument.

Syntaxe

outletk Sname, ksignal

Initialisation

Sname -- Nom sous forme de chaîne de caractères du port sortant. Le nom du connecteur sortant est qualifié implicitement par le nom ou le numéro de l'instrument, si bien qu'il est permis d'utiliser le même nom de connecteur sortant dans plus d'un instrument (mais par contre on ne peut pas utiliser deux fois le même nom de connecteur sortant dans un instrument).

Exécution

ksignal -- signal de taux-k en sortie.

Durant l'exécution, le signal de taux-k passant par le connecteur sortant est envoyé à chaque instance d'un instrument contenant un connecteur entrant auquel ce connecteur sortant a été relié au moyen de l'opcode connect. Les signaux de tous les connecteurs sortants reliés à un connecteur entrant sont additionnés dans le connecteur entrant.

Exemples

Voici un exemple de l'opcode outletk. Il utilise le fichier outletk.csd.

Exemple 644. Exemple de l'opcode outletk.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer> 
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o inletk.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments> 

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

connect "bend", "bendout", "guitar", "bendin" 

instr bend 

kbend line p4, p3, p5 
      outletk "bendout", kbend 
endin 

instr guitar 

kbend inletk "bendin" 
kpch pow 2, kbend/12
     printk2 kpch
asig oscili .4, 440*kpch, 1 
     outs asig, asig
endin 

</CsInstruments> 
<CsScore> 
f1 0 1024 10 1

i"guitar" 0 5 8.00 
i"bend" 3 .2 -12 12 
i"bend" 4 .1 -17 40 
e
</CsScore> 
</CsoundSynthesizer> 


Voir aussi

outleta, outletf, outletkid, inleta, inletk, inletkid, inletf, connect, alwayson, ftgenonce.

Plus d'information sur cet opcode : http://www.csoundjournal.com/issue13/signalFlowGraphOpcodes.html, écrit par Michael Gogins.

Crédits

Par Michael Gogins, 2009