passign

passign — Affecte un ensemble de p-champs à des variables de taux i.

Description

Affecte un ensemble de p-champs à des variables de taux i.

Syntaxe

 ivar1, ... passign [istart]

Initialisation

L'argument optionnel istart donne l'indice du premier p-champ à affecter. La valeur par défaut est 1, ce qui correspond au numéro d'instrument.

Une des variables peut être une variable chaîne de caractères, à laquelle sera affecté dans ce cas le seul paramètre de type chaîne de caractères, s'il y en a un, sinon une erreur.

Exécution

passign transfère les p-champs de l'instrument à des variables de l'instrument, en commençant par celui qui est identifié par l'argument istart. Il ne doit pas y avoir plus de variables que de p-champs, mais il peut y en avoir moins.

Voir aussi

assign,

Exemples

Exemple 634. Une variante de toot8.csd qui utilise passign.

Voici un exemple de l'opcode passign. Il utilise le fichier passign.csd.
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if real audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o passign.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 8

idur,iamp,iskiptime,iattack,irelease,irvbtime,irvbgain  passign   3

kamp      linen     iamp, iattack, idur, irelease
asig      soundin   "fox.wav", iskiptime
arampsig  =         kamp * asig
aeffect   reverb    asig, irvbtime
arvbretrn =         aeffect * irvbgain
;mix dry & wet signals
          outs      arampsig + arvbretrn, arampsig + arvbretrn

          endin

</CsInstruments>
<CsScore>

;ins strt dur  amp  skip atk  rel       rvbt rvbgain
i8   0    4    .3   0    .03  .1        1.5  .3
i8   4    4    .3   1.6  .1   .1        3.1  .7
i8   8    4    .3   0    .5   .1        2.1  .2
i8   12   4    .4   0    .01  .1        1.1  .1
i8   16   4    .5   0.1  .01  .1        0.1  .1

e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur: John ffitch
Université de Bath, Codemist Ltd.
Bath, UK
Décembre 2009

Nouveau dans la version 5.12