polyaft

polyaft — Retourne la pression d'after-touch polyphonique du numéro de note sélectionné.

Description

polyaft retourne la pression polyphonique du numéro de note choisi, optionnellement mappé dans un intervalle défini par l'utilisateur.

Syntaxe

ires polyaft inote [, ilow] [, ihigh]
kres polyaft inote [, ilow] [, ihigh]

Initialisation

inote -- numéro de note. Normalement ajusté à la valeur retournée par notnum

ilow (facultatif, par défaut : 0) -- la valeur de sortie la plus basse

ihigh (facultatif, par défaut : 127) -- la valeur de sortie la plus haute

Exécution

kres -- Pression polyphonique (aftertouch).

Exemples

Voici un exemple de l'opcode polyaft. Il utilise le fichier polyaft.csd.

Ne pas oublier d'inclure l'option -F lorque l'on utilise un fichier MIDI externe comme « polyaft.mid ».

Exemple 770. Exemple de l'opcode polyaft.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in   No messages  MIDI in
-odac           -iadc     -d         -M0  ;;;RT audio I/O with MIDI in
; For Non-realtime ouput leave only the line below:
; -o polyaft.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr	=  44100
ksmps	=  10
nchnls	=  1

	massign 1, 1
itmp	ftgen 1, 0, 1024, 10, 1		; sine wave

	instr 1

kcps	cpsmidib 2		; note frequency
inote	notnum			; note number
kaft	polyaft inote, 0, 127	; aftertouch
; interpolate aftertouch to eliminate clicks
ktmp	phasor 40
ktmp	trigger 1 - ktmp, 0.5, 0
kaft	tlineto kaft, 0.025, ktmp
; map to sine curve for crossfade
kaft	=  sin(kaft * 3.14159 / 254) * 22000

asnd	oscili kaft, kcps, 1

	out asnd

	endin


</CsInstruments>
<CsScore>

t 0 120
f 0 9 2 -2 0
e


</CsScore>
</CsoundSynthesizer>


Crédits

Ajouté grâce à un courriel de Istvan Varga

Nouveau dans la version 4.12