pop

push — Extrait des valeurs de la pile globale. Obsolète.

Description

Extrait des valeurs de la pile globale.

Syntaxe

xval1, [xval2, ... , xval31] pop
ival1, [ival2, ... , ival31] pop

Initialisation

ival1 ... ival31 -- valeurs à extraire de la pile.

Exécution

xval1 ... xval31 -- valeurs à extraire de la pile.

Les valeurs données sont extraites de la pile. La pile globale fonctionne en mode dernier entré, premier sorti : après de multiples appels à push, il faut utiliser pop dans l'ordre inverse.

Chaque opération push ou pop peut traiter un "paquet" de variables. Lorsque l'on utilise pop, le nombre, le type et l'ordre des éléments doivent être les mêmes que ceux utilisés par le push correspondant. Ainsi après un "push Sfoo, ibar", il faut un appel comme "Sbar, ifoo pop", et pas, par exemple deux instructions "pop" séparées.

Les opcodes push et pop acceptent des variables de n'importe quel type (taux-i, -k, -a et chaînes de caractères). On peut utiliser n'importe quelle combinaison de types-i, -k, -a ou -S. Les variables de type 'a' et 'k' ne sont passées que pendant l'exécution, tandis que celles de type 'i' et 'S' ne sont passées que pendant l'initialisation.

push/pop pour les types a, k, i et S copient les données par valeur. Au contraire, push_f ne pousse qu'une référence du f-signal et le pop_f correspondant copiera directement depuis la variable originale dans le signal de sortie. Pour cette raison, il n'est pas recommandé de changer le f-signal source de push_f avant l'appel à pop_f. De même, si l'instance d'instrument possédant la variable passée à push_f est désactivée avant que pop_f ne soit appelé, il peut en résulter un comportement indéfini.

Toutes les erreurs de pile (tentative de pousser des données alors qu'il n'y a plus d'espace ou d'extraire des données d'une pile vide, nombre ou types d'arguments inconsistants, etc) sont fatales et terminent l'exécution.

Exemples

Voici un exemple de l'opcode pop. Il utilise le fichier pop.csd.

Exemple 1231. Exemple de l'opcode pop.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer> 
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o pop.wav -W ;;; for file output any platform
</CsOptions> 
<CsInstruments> 

sr = 44100 
ksmps = 32 
0dbfs  = 1 
nchnls = 2

stack 100000 

instr 1 

a1	oscils 0.7, 220, 0 
k1	line 0, p3, 1 
        push "blah", 123.45, a1, k1 
        push rnd(k1) 

k_rnd	pop 
S01, i01, a01, k01 pop 
        printf_i "S01 = '%s', i01 = %g\n", 1, S01, i01 
ktrig	metro 5.0 
        printf "k01 = %.3f, k_rnd = %.3f\n", ktrig, k01, k_rnd 
        outs a01, a01 

endin 
</CsInstruments> 
<CsScore> 

i 1 0 5 
e 
</CsScore> 
</CsoundSynthesizer> 


Voir aussi

stack, push, pop_f and push_f.

L'utilisation de cet opcode relève un peu du bricolage comme on peut le lire ici : http://csound.1045644.n5.nabble.com/passing-a-string-to-a-UDO-td1099284.html.

Crédits

Par Istvan Varga.

2006

Obsolète depuis la version 6.04.