poscil

poscil — Oscillateur haute précision.

Description

Oscillateur haute précision.

Syntaxe

ares poscil aamp, acps [, ifn, iphs]
ares poscil aamp, kcps [, ifn, iphs]
ares poscil kamp, acps [, ifn, iphs]
ares poscil kamp, kcps [, ifn, iphs]
ires poscil kamp, kcps [, ifn, iphs]
kres poscil kamp, kcps [, ifn, iphs]

Initialisation

ifn (facultatif) -- numéro de la table de fonction. Vaut -1 par défaut ce qui indique une onde sinus.

iphs (facultatif, par défaut 0) -- phase initiale (table normalisée, index 0-1). Si une valeur négative est donnée, l'initialisation de la phase est ignorée.

Exécution

ares -- signal de sortie

kamp, aamp -- l'amplitude du signal de sortie.

kcps, acps -- la fréquence du signal de sortie en Hz.

poscil (oscillateur de précision) est identique à oscili, mais il permet un contrôle de la fréquence plus précis, en particulier lorsque l'on utilise de grandes tables avec de faibles valeurs de fréquence. Il utilise une indexation de la table en virgule flottante, au lieu de l'arithmétique entière utilisée par oscil et oscili. Il est à peine plus lent que oscili.

Depuis Csound 4.22, poscil accepte aussi des valeurs de fréquence négatives et il peut utiliser des valeurs de taux-a aussi bien pour l'amplitude que pour la fréquence. Ainsi, cet opcode permet la modulation d'amplitude (MA) et la modulation de fréquence (MF).

L'opcode poscil3 est le même que poscil, mais il utilise une interpolation cubique.

Noter que poscil peut utiliser des tables de longueur différée (non puissance de deux).

Exemples

Voici un exemple de l'opcode poscil. Il utilise le fichier poscil.csd.

Exemple 708. Exemple de l'opcode poscil.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o poscil.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

seed 0
gisine ftgen 0, 0, 2^10, 10, 1

instr 1

ipeak random 0, 1 		;where is the envelope peak
asig  poscil .8, 220, gisine
aenv  transeg 0, p3*ipeak, 6, 1, p3-p3*ipeak, -6, 0
aL,aR pan2 asig*aenv, ipeak	;pan according to random value
      outs aL, aR

endin

</CsInstruments>
<CsScore>
i1 0 5
i1 4 5
i1 8 5
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

poscil3

Crédits

Auteur : Gabriel Maldonado
Italie
1998

Novembre 2002. Ajout d'une note sur les changements dans la version 4.22 de Csound, merci à Rasmus Ekman.

Nouveau dans la version 3.52 de Csound.

La table de fonction est facultative depuis la version 6.0 de Csound.

La possibilité d'ignorer l'initialisation a été ajoutée dans la version 6.06.