puts

puts — Imprime une chaîne de caractères constante ou variable.

Description

puts imprime une chaîne de caractères terminée par un retour à la ligne facultatif chaque fois que le signal de déclenchement est positif et change de valeur.

Syntaxe

puts Sstr, ktrig[, inonl]

Initialisation

Sstr -- chaîne à imprimer.

inonl (facultatif, 0 par défaut) -- s'il est différent de zéro, désactive l'impression automatique d'un retour à la ligne à la fin de la chaîne.

Exécution

ktrig -- signal de déclenchement, doit être valide au temps-i. La chaîne est imprimée à l'initialisation si ktrig est positif, et pendant l'exécution chaque fois que ktrig est positif et différent de sa valeur précédente. Utiliser une valeur constante de 1 pour n'imprimer qu'une fois à l'initialisation de la note.

Exemples

Voici un exemple de l'opcode puts. Il utilise le fichier puts.csd.

Exemple 728. Exemple de l'opcode puts.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o puts.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr	1

kcount init 440
ktrig  metro 10
kcount = kcount + ktrig
String sprintfk "frequency in Hertz : %d \n", kcount
       puts	String, kcount
       asig poscil .7, kcount, 1
       outs asig, asig
	
endin
</CsInstruments>
<CsScore>
f1 0 16384 10 1

i 1 0 10
e
</CsScore>
</CsoundSynthesizer>


Sa sortie contiendra des lignes comme celles-ci :

frequency in Hertz : 440 
frequency in Hertz : 441 
frequency in Hertz : 442 
....
frequency in Hertz : 459 
frequency in Hertz : 460 

Crédits

Auteur : Istvan Varga
2005