pvsbin

pvsbin — Obtient les valeurs d'amplitude et de fréquence d'un bin de signal PVS.

Description

Obtient les valeurs d'amplitude et de fréquence d'un bin de signal PVS, comme variables de taux-k.

Syntaxe

kamp, kfr pvsbin fsig, kbin

Exécution

kamp -- amplitude du bin

kfr -- fréquence du bin

fsig -- flot d'entrée pv

kbin -- numéro du bin

Exemples

Voici un exemple de l'opcode pvsbin. Il utilise le fichier pvsbin.csd. Cet exemple utilise une entrée en temps réel, mais on peut aussi utiliser un fichier son en entrée.

Exemple 706. Exemple de l'opcode pvsbin

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac           -iadc    ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o pvsbin.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
kr = 4410
ksmps = 10
nchnls = 1

instr 1
ifftsize = 1024  
iwtype = 1    /* cleaner with hanning window */

;a1   soundin "input.wav"  ;select a soundifle
a1 inch 1   ;Use realtime input

fsig pvsanal   a1, ifftsize, ifftsize/4, ifftsize, iwtype
kamp, kfr pvsbin   fsig, 10
adm  oscil     kamp, kfr, 1

       out    adm
endin

</CsInstruments>
<CsScore>
; sine wave
f 1 0 4096 10 1

i 1 0 30
e

</CsScore>
</CsoundSynthesizer>


Voir aussi

pvsanal, pvsynth, pvsadsyn

Crédits

Auteur : Victor Lazzarini
Août 2006