pvsceps

pvsceps — Calcule le cepstre d'une entrée pvs, avec coefficients de liftrage facultatifs.

Description

Syntaxe

keps[] pvsceps fsig[, icoefs]

Initialisation

icoefs -- le nombre de coefficients retenus dans le cepstre en sortie. Par défaut, aucun coefficient n'est liftré.

Exécution

keps[] -- le cepstre en sortie, un tableau de taille N/2+1, où N est est équivalent à la taille de le TFR du fsig en entrée.

fsig -- un flux pv en entrée.

Exemples

Voici un exemple d'utilisation de l'opcode pvsceps. Il utilise le fichier pvsceps.csd.

Exemple 749. 

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

<CsoundSynthesizer>
<CsOptions>
</CsOptions>
<CsInstruments>

instr 1

a1 diskin "fox.wav",1,0,1
k1 randh  80, 2.5
a2 vco2  8, 220+k1
fsig pvsanal a1,1024,256,1024,1
fsig2 pvsanal a2,1024,256,1024,1
keps[] pvsceps fsig,30
kenv[] cepsinv keps
fenv tab2pvs r2c(kenv)
fvoc pvsfilter fsig2, fenv, 1
asig pvsynth fvoc

    out asig
endin


</CsInstruments>
<CsScore>
i1 0 60
</CsScore>
</CsoundSynthesizer>


Voir aussi

pvsanal, pvsynth, pvsadsyn, pvspitch

Crédits

Auteur : Victor Lazzarini
2014