pvsfwrite

pvsfwrite — Ecrit un signal fsig dans un fichier PVOCEX.

Description

Cet opcode écrit un signal fsig dans un fichier PVOCEX (qui peut être lu à son tour par pvsfread ou par d'autres programmes qui supportent les fichiers PVOCEX en entrée).

Syntaxe

pvsfwrite fsig, ifile

Initialisation

fsig -- données du fsig en entrée. ifile -- nom du fichier (une chaîne de caractères entre guillemets) .

Exemples

Voici un exemple de l'opcode pvsfwrite. Il utilise le fichier pvsfwrite.csd. Cet exemple utilise une entrée temps réel.

Exemple 726. Exemple de l'opcode pvsfwrite

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in
-odac           -iadc    ;;;RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o pvsfwrite.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
kr = 4410
ksmps = 10
nchnls = 1

;By Victor Lazzarini 2008

instr 1
asig oscili 10000, 440, 1
fss pvsanal  asig, 1024,256,1024,0
pvsfwrite fss, "mypvs.pvx"
ase pvsynth fss
           out ase
endin

instr 2 ; must be called after instr 1 finishes
ktim timeinsts
fss  pvsfread ktim, "mypvs.pvx"
asig pvsynth fss
  out asig
endin

</CsInstruments>
<CsScore>
f1 0 16384 10 1
i1 0   1
i2 1   1
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

pvsanal, pvsynth, pvsadsyn

Crédits

Auteur : Victor Lazzarini
Novembre 2004

Nouveau greffon dans la version 5

Novembre 2004.