pvslock

pvslock — Verrouille en fréquence un fsig d'entrée.

Description

Cet opcode recherche les crêtes spectrales puis il verrouille les fréquences autour de ces crêtes. C'est l'analogue d'un verrouillage de phase dans le traitement PV statique. On peut l'utiliser pour améliorer la qualité de l'étirement des durées et de la transposition des hauteurs dans le traitement PV.

Syntaxe

fsig pvslock fsigin, klock

Exécution

fsig -- flot pv de sortie.

fsigin -- flot pv d'entrée.

klock -- verrouillage de fréquence, 1 -> verrouillé, 0 -> non verrouillé (passant).

[Avertissement] Avertissement

Il est dangereux d'utiliser la même variable-f à la fois comme entrée et comme sortie des opcodes pvs. Ceci peut produire un comportement indéfini de certains de ces opcodes. Utilisez une variable différente à gauche et à droite de l'opcode.

Exemples

Voici un exemple de l'opcode pvslock. Il utilise le fichier pvslock.csd.

Exemple 734. Exemple de l'opcode pvslock.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o pvslock.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

gifil ftgen 0, 0, 0, 1, "fox.wav", 0, 0, 1

instr 1

klock	= p4
fsig    pvstanal 1, 1, 1, gifil	; no further transformations		
fsigout	pvslock  fsig, klock	; lock frequency 
aout    pvsynth  fsigout
        outs     aout, aout

endin
</CsInstruments>
<CsScore>
          
i 1 0 2.6 1	; locked
i 1 3 2.6 0	; not locked     

e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Victor Lazzarini
Novembre 2004

Nouveau greffon dans la version 5

Novembre 2004.