pvsmix

pvsmix — Mélange "sans accroc" deux signaux pv.

Description

Mélange "sans accroc" deux signaux pv. Cet opcode combine les composantes les plus proéminentes de deux flots pvoc en un seul flot mélangé.

Syntaxe

fsig pvsmix fsigin1, fsigin2

Exécution

fsig -- flot pv de sortie

fsigin1 -- flot pv d'entrée

fsigin2 -- flot pv d'entrée, qui doit avoir le même format que fsigin1.

[Avertissement] Avertissement

Il est dangereux d'utiliser la même variable-f à la fois comme entrée et comme sortie des opcodes pvs. Ceci peut produire un comportement indéfini de certains de ces opcodes. Utilisez une variable différente à gauche et à droite de l'opcode.

Exemples

Voici un exemple de l'opcode pvsmix. Il utilise le fichier pvsmix.csd.

Exemple 845. Exemple de l'opcode pvsmix.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac  ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o pvsmix.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

; by Menno Knevel 2021

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

asig1 diskin2 "beats.wav", .5,0,1		;signal in 1 at half speed
asig2 diskin2 "beats.wav", 1,0,1		;signal in 2
fsig1 pvsanal asig1,1024,256,1024,0	      ;pvoc analysis 
fsig2 pvsanal asig2,1024,256,1024,0	      ;of both signals
fsall pvsmix  fsig1, fsig2 
asig  pvsynth fsall
outs asig, asig 

endin 
</CsInstruments>
<CsScore>

i 1 0 8
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Victor Lazzarini
Novembre 2004

Nouveau greffon dans la version 5

Novembre 2004.