readf

readf — Lit une ligne de texte depuis un fichier externe.

Description

Lit une ligne de texte depuis un fichier externe à chaque k-cycle.

Syntaxe

Sres, kline readf ifilname

Initialisation

ifilname -- un entier N indiquant un fichier nommé "input.N" ou une chaîne de caractères (entre guillemets, espaces autorisés) contenant le nom du fichier externe. Si c'est une chaîne de caractères, elle peut être un nom de chemin complet avec un répertoire spécifié ou bien un simple nom de fichier. Dans ce dernier cas, le fichier est d'abord cherché dans le répertoire courant, puis dans SSDIR et finalement dans SFDIR.

Exécution

Sres -- variable contenant la ligne lue depuis ifilname.

kline -- numéro de la ligne lue ou -1 si la fin du fichier est atteinte.

Cet opcode permet de lire une ligne de texte depuis un fichier externe nommé. Il peut y avoir n'importe quel nombre d'opcodes readf dans un instrument ou dans un orchestre, mais ils lisent séparément depuis le même fichier ou depuis différents fichiers.

Exemples

Voici un exemple de l'opcode readf. Il utilise le fichier readf.csd.

Exemple 772. Exemple de l'opcode readf.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
-n
</CsOptions>
<CsInstruments>
instr 1
  Swd           pwd
                printf_i      "Working directory is '%s'\n", 1, Swd
                prints        "Reading myself =):\n"
read:
  Sline, kLinNum readf "readf.csd"
                printf "Line %d: %s", kLinNum, kLinNum, Sline
  if kLinNum != -1 then
                kgoto read
  else 
                turnoff
  endif
endin
</CsInstruments>
<CsScore>
i1 0 1
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

readfi.

Crédits

John ffitch et Joachim Heintz

2012 ; nouveau dans la version 5.17.12