readscore

readscore — Lecture, prétraitement et planification d'une partition depuis une chaîne.

Description

readscore produit un ou plusieurs évènements de partition. Il gère les chaînes de caractères dans les mêmes conditions que la partition standard, y compris le prétraitement (report, tri, rampes, etc). Les chaînes sur plusieurs lignes sont acceptées et elles sont délimitées par {{ }}.

Syntaxe

readscore Sin 

Initialisation

« Sin » -- une chaîne de caractères entre guillemets ou délimitée par {{ }} et contenant un ou plusieurs évènements de partition.

Exemples

Voici un exemple de l'opcode readscore. Il utilise le fichier readscore.csd.

Exemple 779. Exemple de l'opcode readscore.

Voir les sections Audio en temps réel et Options de la ligne de commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
-d -o dac
</CsOptions>
<CsInstruments>
   
 
instr 1
a1 flooper2 1000,p4,2,5,0.1,1 
   out a1
endin

instr 2
ires readscore {{
{12  COUNT 
i1 $COUNT 1 [1 + $COUNT/12]
}
}}
endin
 
</CsInstruments>
<CsScore>
f0 12
f 1 0 0 1 "fox.wav" 0 0 1

i2 0 1



</CsScore>
</CsoundSynthesizer>

On peut utiliser des opcodes de chaîne de caractères comme sprintfk pour générer les chaînes à passer à readscore comme ceci :

Sfil = "/Volumes/Bla/file.aif"
String  sprintfk {{i 2 0 %f "%s" %f %f %f %f}}, idur, Sfil, p5, p6, knorm, iskip
readscore String
 


Voir aussi

event, event_i, schedule, schedwhen, schedkwhen, schedkwhennamed

Crédits

Auteur : Victor Lazzarini, 2013