scalearray

scalearray — Mise à l'échelle des valeurs dans une partie d'un vecteur (tableau unidimensionnel).

Description

L'opcode scalearray met à l'échelle une partie d'un vecteur entre un minimum et un maximum donnés.

Syntaxe

scalearray tarray, kmin, kmax[, kleft, kright]

Exécution

karray -- tableau pour l'opération.

kmin, kmax -- valeurs du minimum et du maximum de la cible.

kleft, kright -- partie de la table à utiliser, s'étendant par défaut de 0 à la taille du vecteur.

Exemples

Voici un exemple de l'opcode scalearray. Il utilise le fichier scalearray.csd.

Exemple 812. Exemple de l'opcode scalearray.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-n 
</CsOptions>
<CsInstruments>
;example by joachim heintz

           seed       0

instr 1
;create an array with 10 elements
kArr[]     init       10
;fill in random numbers and print them out
           printks    "kArr in maximum range 0..100:\n", 0
kIndx      =          0
  until kIndx == 10 do
kNum       random     0, 100
kArr[kIndx] =         kNum
           printf     "kArr[%d] = %10f\n", kIndx+1, kIndx, kNum
kIndx      +=         1
  od
;scale numbers 0...1 and print them out again
           scalearray kArr, 0, 1
kIndx      =          0
           printks    "kArr in range 0..1\n", 0
  until kIndx == 10 do
           printf     "kArr[%d] = %10f\n", kIndx+1, kIndx, kArr[kIndx]
kIndx      +=         1
  od
           turnoff
endin
</CsInstruments>
<CsScore>
i1 0 0.1
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

maxarray, minarray, sumarray,

Crédits

Auteur : John ffitch
Octobre 2011

Nouveau dans la version 5.14 de Csound.