scantable

scantable — Une implémentation simplifiée de la synthèse par balayage.

Description

Une implémentation simplifiée de la synthèse par balayage. C'est l'implémentation d'une corcde circulaire parcourue au moyen de tables externes. Cet opcode permet la modification directe et la lecture des valeurs avec les opcodes de table.

Syntaxe

aout scantable kamp, kpch, ipos, imass, istiff, idamp, ivel

Initialisation

ipos -- table contenant le tableau de position.

imass -- table contenant la masse de la corde.

istiff -- table contenant la raideur de la corde.

idamp -- table contenant les facteurs d'atténuation de la corde.

ivel -- table contenant les vitesses.

Exécution

kamp -- amplitude (gain) de la corde.

kpch -- la fréquence de balayage de la corde.

Exemples

Voici un exemple de l'opcode scantable. Il utilise le fichier scantable.csd.

Exemple 851. Exemple de l'opcode scantable.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac -+rtmidi=virtual -M0 ;;;realtime audio out and midi in
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o scantable.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

gi1 ftgen 1, 0, 128, 7, 0, 64, 1, 64, 0		; initial position
gi2 ftgen 2, 0, 128, -7, 1, 128, 1		; masses
gi3 ftgen 3, 0, 128, -7, 0, 64, 100, 64, 0	; stiffness
gi4 ftgen 4, 0, 128, -7, 1, 128, 1		; damping
gi5 ftgen 5, 0, 128, -7, 0, 128, 0.5		; initial velocity


instr 1

iamp ampmidi .5
ipch cpsmidi 
kenv madsr .1, .1, .8, .3

asig scantable iamp, ipch, 1, 2, 3, 4, 5
asig dcblock asig
     outs asig*kenv, asig*kenv

endin
</CsInstruments>
<CsScore>

f0 60	; play for 60 seconds
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

scanhammer

Plus d'information sur cet opcode : http://www.csounds.com/stevenyi/scanned/yi_scannedSynthesis.html , écrit par Steven Yi.

Crédits

Auteur : Matt Gilliard
Avril 2002

Nouveau dans la version 4.20