schedkwhennamed

schedkwhennamed — Semblable à schedkwhen mais avec un instrument nommé dans la phase d'initialisation.

Description

Semblable à schedkwhen mais avec un instrument nommé dans la phase d'initialisation.

Syntaxe

schedkwhennamed ktrigger, kmintim, kmaxnum, "name", kwhen, kdur \
      [, ip4] [, ip5] [...]

Initialisation

ip4, ip5, ... -- Equivalent à p4, p5, etc., dans une instruction i de partition.

Exécution

ktrigger -- déclenche un nouvel évènement de partition. Si ktrigger = 0, aucun nouvel évènement n'est déclenché.

kmintim -- intervalle de temps minimum entre les évènements générés, en secondes. Si kmintim est inférieur ou égal à 0, il n'y a aucune limite de temps.

kmaxnum -- nombre maximum d'instances simultanées de l'instrument nommé autorisées. Si le nombre d'instances existantes de l'instrument nommé est supérieur ou égal à kmaxnum, aucun nouvel évènement n'est généré. Si kmaxnum est inférieur ou égal à 0, il n'est pas utilisé pour limiter la génération d'évènement.

"name" -- le nom de l'instrument.

kwhen -- date de début du nouvel évènement. Equivalent à p2 dans une instruction i de partition. Mesurée à partir de l'instant de l'évènement déclencheur. kwhen doit être supérieure ou égale à 0. Si kwhen est supérieure à 0, l'instrument ne sera pas initialisé jusqu'à ce que cette date soit atteinte.

kdur -- durée de l'évènement. Equivalent à p3 dans une instruction i de partition. Si kdur vaut 0, l'instrument ne fera qu'une phase d'initialisation, sans exécution. Si kdur est négatif, une note tenue est démarrée. (Voir ihold et instruction i.)

[Note] Note

Dans l'attente d'évènements à déclencher par schedkwhennamed, l'exécution doit continuer, ou Csound pourrait se terminer si aucun évènement de partition n'est attendu. Pour garantir une exécution continue, on peut utiliser une instruction f0 dans la partition.

[Note] Note

Noter que l'opcode schedkwhennamed ne peut pas accepter de p-champs chaîne de caractère. Si vous devez passer des chaînes de caractère à l'instanciation d'un instrument, utilisez l'opcode scoreline ou scoreline_i.

Exemples

Voici un exemple de l'opcode schedkwhennamed. Il utilise le fichier schedkwhennamed.csd.

Exemple 938. Exemple de l'opcode schedkwhennamed.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in    No messages
-odac           -iadc     -d
; For Non-realtime ouput leave only the line below:
; -o schedkwhennamed.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

  sr	    =  48000
  ksmps	    =  16
  nchnls    =  2
  0dbfs	    =  1

; Example by Jonathan Murphy 2007

  gSinstr2  =  "printer"

    instr 1

  ktrig	    metro     1
if (ktrig == 1) then
  ;Call instrument "printer" once per second
	    schedkwhennamed   ktrig, 0, 1, gSinstr2, 0, 1

endif

    endin

    instr printer

  ktime	    timeinsts
	    printk2   ktime

    endin

</CsInstruments>
<CsScore>
i1 0 10
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

event, event_i, schedule, schedwhen, schedkwhen, scoreline, scoreline_i

Crédits

Auteur : Rasmus Ekman
EMS, Stockholm, Suède

Nouveau dans la version 4.23 de Csound