scoreline_i

scoreline_i — Délivre un ou plusieurs évènements de ligne de partition depuis un instrument pendant la phase d'initialisation.

Description

scoreline_i délivre des évènements de partition au cours de la phase d'initialisation. Il peut gérer les chaînes de caractères dans les mêmes conditions que dans la partition standard. Les chaînes de caractères sur plusieurs lignes sont acceptées, en utilisant {{ }} pour encadrer la chaîne de caractères.

Syntaxe

scoreline_i Sin

Initialisation

« Sin » -- une chaîne de caractères (entre guillemets ou encadrée par {{ }}), contenant un ou plusieurs évènements de partition.

Exemples

Voici en exemple de l'opcode scoreline_i. Il utilise le fichier scoreline_i.csd.

Exemple 857. Exemple de l'opcode scoreline_i.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac --old-parser   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o scoreline.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

scoreline_i {{
            i 2  0  3  "flute.aiff"
            i 2  1  3  "beats.wav"
            }}
        
endin

instr 2

asig soundin p4
     outs asig*.8, asig*.8

endin
</CsInstruments>
<CsScore>

i1 0 1
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

event, event_i, schedule, schedwhen, schedkwhen, schedkwhennamed, scoreline

Pour plus d'information sur cet opcode : http://www.csoundjournal.com/issue15/phrase_loops.html , écrit par Jim Aikin.

Egalement dans les Floss Manuals : http://en.flossmanuals.net/csound/ch020_e-triggering-instrument-events/ .

Crédits

Auteur : Victor Lazzarini, 2007