sfplist

sfplist — Imprime une liste de tous les presets d'un fichier d'échantillons SoundFont2 (SF2).

Description

Imprime une liste de tous les presets d'un fichier d'échantillons SoundFont2 (SF2) préalablement chargé en mémoire. Ces opcodes permettent la gestion de la structure d'échantillon des fichiers SF2. Afin de comprendre l'utilisation de ces opcodes, il faut connaître le format SF2 dont on peut trouver une brève description dans l'annexe Format de Fichier SoundFont2.

Syntaxe

sfplist ifilhandle

Initialisation

ifilhandle -- nombre unique généré par l'opcode sfload à utiliser comme identificateur pour un fichier SF2. On peut charger et activer plusieurs fichiers SF2 en même temps.

Exécution

sfplist imprime sur la console une liste de tous les presets d'un fichier (SF2) préalablement chargé en mémoire.

Ces opcodes ne supportent que la structure d'échantillon des fichiers SF2. La structure de modulateur du format SoundFormat2 n'est pas supportée dans Csound. Tout traitement ou modulation des données échantillonnées est à la charge de l'utilisateur de Csound, ce qui permet de s'affranchir de toutes les restrictions imposées par le standard SF2.

Exemples

Voici un exemple de l'opcode sfplist. Il utilise le fichier sfplist.csd.

Exemple 846. Exemple de l'opcode sfplist.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac -+rtmidi=virtual -M0  ;;;realtime audio out, virtual midi in
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o sfplist.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

gisf	sfload	 "sf_GMbank.sf2"
	sfplist	 gisf					;list all presets
gir	sfpreset 125, 3, gisf, 0 			;preset = Car Pass

instr 1	; play from score and midi keyboard

	mididefault	60, p3
	midinoteonkey	p4, p5
inum	init	p4
ivel	init	p5
ivel	init	ivel/127				;make velocity dependent
kamp	linsegr	1, 1, 1, .1, 0
kamp	= kamp/6000					;scale amplitude
kfreq	init	1					;do not change freq from sf
a1,a2	sfplay3	ivel, inum, kamp, kfreq, gir
	outs	a1, a2
	
endin
	
</CsInstruments>
<CsScore>
f0  60				; stay active for 1 minute

i1 0 1 60 127
i1 + 1 62 <
i1 + 1 65 <
i1 + 1 69 10

e
</CsScore>
</CsoundSynthesizer>


Sa sortie comprendra des lignes comme celles-ci :

Preset list of "sf_GMbank.sf2"
  0) Piano 1                   prog:0   bank:0
  1) Piano 2                   prog:1   bank:0
  2) Piano 3                   prog:2   bank:0
  3) Honky Tonk                prog:3   bank:0
  4) E.Piano 1                 prog:4   bank:0
  5) E.Piano 2                 prog:5   bank:0
  6) Harpsichord               prog:6   bank:0
  ........
  146) Car-Pass                prog:125 bank:3
  ........

Voir aussi

sfilist, sfinstr, sfinstrm, sfload, sfpassign, sfplay, sfplaym, sfpreset

Crédits

Auteur : Gabriel Maldonado
Italie
Mai 2000

Nouveau dans la version 4.07 de Csound