strsub

strsub — Extrait une sous-chaîne de caractères.

Description

Retourne une sous-chaîne d'une chaîne source. strsub ne s'exécute que pendant l'initialisation.

Syntaxe

Sdst strsub Ssrc[, istart[, iend]]

Initialisation

istart (facultatif, 0 par défaut) -- position du début dans Ssrc, comptée à partir de 0. Une valeur négative signifie à partir de la fin de la chaîne.

iend (facultatif, 1 par défaut) -- position de la fin dans Ssrc, comptée à partir de 0. Une valeur négative signifie à partir de la fin de la chaîne. Si iend est inférieure à istart, la sortie est inversée.

Exemples

Voici un exemple de l'opcode strsub. Il utilise le fichier strsub.csd.

Exemple 958. Exemple de l'opcode strsub.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
; Audio out   Audio in    No messages
-odac           -iadc     ;;;-d     RT audio I/O
; For Non-realtime ouput leave only the line below:
; -o strsub.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>
; By: Jonathan Murphy 2007

instr 1
    Smember strget p4

    ; Parse Smember
    istrlen    strlen   Smember
    idelimiter strindex Smember, ":"

    S1    strsub Smember, 0, idelimiter  ; "String1"
    S2    strsub Smember, idelimiter + 1, istrlen  ; "String2"

    printf "First string: %s\nSecond string: %s\n", 1, S1, S2

endin

</CsInstruments>
<CsScore>
i 1 0 1 "String1:String2"
</CsScore>
</CsoundSynthesizer>


Voir aussi

strsubk

Crédits

Auteur : Istvan Varga
2006