sum

sum — Somme de n'importe quel nombre de signaux de taux-a ou des éléments d'un tableau.

Description

Somme de n'importe quel nombre de signaux de taux-a ou des éléments d'un tableau.

Syntaxe

ares sum asig1 [, asig2] [, asig3] [...]
kres sum karr
ires sum iarr

Exécution

asig1, asig2, ... -- signaux de taux-a à additionner (à mélanger).

karr, iarr -- tableaux unidimensionnels.

Exemples

voici un exemple de l'opcode sum. Il utilise le fichier sum.csd.

Exemple 1052. Exemple de l'opcode sum.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o sum.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

gisine ftgen 0, 0, 2^10, 10, 1

instr 1

a1   oscili 1, 10.0, gisine		;combine 3 sinusses
a2   oscili 1, 1.0, gisine		;at different rates
a3   oscili 1, 3.0, gisine
ares sum a1, a2, a3			;sum them

ares = ares*100				;scale result and
asig poscil .5, ares+110, gisine	;add to frequency			
     outs asig, asig

endin
</CsInstruments>
<CsScore>

i1 0 5
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Gabriel Maldonado
Italie
Avril 1999

Nouveau dans le version 3.54 de Csound

Ajouts pour les tableaux dans la version 6.09