tablexseg

tablexseg — Crée une nouvelle table de fonction en faisant des segments d'exponentielle entre les valeurs de tables de fonction en mémoire.

Description

tablexseg est comme expseg mais il interpole entre des valeurs stockées dans des tables de fonction. Le résultat est une nouvelle table de fonction passée en interne à tout vpvoc apparaissant avant le tablexseg suivant (même fonctionnement que pour les paires lpread/lpreson). Les utilisations possibles sont décrites plus loin dans la notice de vpvoc.

Syntaxe

tablexseg ifn1, idur1, ifn2 [, idur2] [, ifn3] [...]

Initialisation

ifn1, ifn2, ifn3, etc. -- numéros des tables de fonction. ifn1, ifn2, et les suivantes, doivent avoir la même taille.

idur1, idur2, etc. -- durée de l'interpolation d'une table à l'autre.

Exemples

Voici un exemple de l'opcode tablexseg. Il utilise le fichier tablexseg.csd.

Exemple 985. Exemple de l'opcode tablexseg.

Voir les sections Audio en Temps Réel et Options de la Ligne de Commande pour plus d'information sur l'utilisation des options de la ligne de commande.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o tablexseg.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1
; analyze "fox.wav" with PVANAL first
iend  = p4
ktime line 0, p3, iend
      tablexseg p5, p3, p6		;morph from table 1
asig  vpvoc ktime, 1, "fox.pvx"		;to table 2
      outs asig*3, asig*3

endin      
</CsInstruments>
<CsScore>
f 1 0 512 9 .5 1 0
f 2 0 512 5 1 60 0.01 390 0.01 62 1

i 1 0 5 2.7 1 2
e
</CsScore>
</CsoundSynthesizer>


Voir aussi

pvbufread, pvcross, pvinterp, pvread, tableseg

Crédits

Auteur : Richard Karpen
Seattle, WA USA
1997